User Tools

Site Tools


mozilla:sessionstorebackup

SessionStoreBackup

Riferimento: Gioxx (dev@gfsolone.com)
Versione ultimo pacchetto: 0.5

E’ dai tempi di Firefox 2 che Mozilla ha introdotto una funzionalità in grado di salvare le proprie tab aperte all’atto della chiusura del browser, dando poi la possibilità di riprendere il lavoro lasciato a metà in un secondo momento. Amata e odiata allo stesso tempo, questa funzione è ancora oggi presente (grazie a Panorama), fondamentale per chi ne ha sempre fatto uso, come “se non ci fosse” per chi è abituato a tenere qualche sito aperto ed è in grado di terminare il proprio lavoro prima di chiudere il browser.

Io ricado nel primo gruppo, e come promesso sul forum di Mozilla Italia nella discussione dedicata alla accidentale perdita di tab lasciate aperte, voglio scrivere qualche riga che vi permetta di aiutarvi nell’impresa del non perdere mai il proprio lavoro.

Sul blog

Trovate tutte le informazioni sul codice e sul suo lavoro nell'articolo dedicato sul mio blog:
http://gioxx.org/2011/07/11/firefox-sessionstore-backup/

Codice sorgente

Arrivato alla versione 0.5 che modifica un semplice controllo rispetto alla 0.4 di ottobre 2011:

SessionStoreBackup.bat
REM Inserire il nome della cartella del profilo qui di seguito
REM Se non sai cosa fare, leggi http://wp.me/pdQ5q-1BY
 
set NOMEPROFILO=NOMEPROFILO.default
 
REM NON TOCCARE NIENTE DA QUI IN POI!
 
@echo off
 
cls
echo SessionStoreBackup 0.5
echo Gioxx - gf.solone@mozillaitalia.org
echo Info: http://wp.me/pdQ5q-1BY
echo;
 
:Preparazione
echo;
echo Lettura directory e file di salvataggio sessione ...
echo;
 
set sessionFileDir=%appdata%\Mozilla\Firefox\Profiles\%NOMEPROFILO%\
set sessionFileName=sessionstore
set sessionFileSuffix=.js
 
if not exist %sessionFileDir%SessionStoreBackup mkdir %sessionFileDir%SessionStoreBackup
 
set stampH=%time:~0,2%
if %stampH% lss 10 (set stampH=0%time:~1,1%)
set stampM=%time:~3,2%
set stampS=%time:~6,2%
set stampU=%time:~9,2%
set sessionVer=%stampH%%stampM%%stampS%%stampU%
 
echo Fatto.
echo;
 
:Start
IF NOT EXIST "%sessionFileDir%%sessionFileName%%sessionFileSuffix%" (GOTO :End)
IF NOT EXIST "%sessionFileDir%%sessionFileName%-%sessionVer%%sessionFileSuffix%" (
echo Creo il file di backup ...
echo;
copy "%sessionFileDir%%sessionFileName%%sessionFileSuffix%" "%sessionFileDir%%sessionFileName%-%sessionVer%%sessionFileSuffix%"
echo;
echo Sposto il file nella cartella di backup ...
echo;
move "%sessionFileDir%%sessionFileName%-%sessionVer%%sessionFileSuffix%" "%sessionFileDir%SessionStoreBackup\"
echo;
echo Backup completato in
echo %sessionFileDir%SessionStoreBackup\%sessionFileName%-%sessionVer%%sessionFileSuffix%
echo;
)
 
:PuliziaFile
echo Pulizia file obsoleti ...
echo;
if not exist %windir%\..\temp\OldSessions mkdir %windir%\..\temp\OldSessions
robocopy %sessionFileDir%SessionStoreBackup %windir%\..\temp\OldSessions /E /MOV /MINAGE:3 /R:10
rd %windir%\..\temp\OldSessions /s /q
echo Fatto.
 
:End
mozilla/sessionstorebackup.txt · Last modified: 2013/11/15 12:38 by Giovanni